build.gradle

buildscript {
  configurations.classpath {
    resolutionStrategy.activateDependencyLocking()
  }
}

plugins {
  id('checkstyle')
  id('java-gradle-plugin')

  alias(libs.plugins.pluginPublish)
  alias(libs.plugins.prettyJupiter)
  alias(libs.plugins.sonarlint)
  alias(libs.plugins.strictNullCheck)
}

group = 'io.github.joselion'

java {
  sourceCompatibility = JavaLanguageVersion.of(17)
  toolchain {
    languageVersion = JavaLanguageVersion.of(23)
    vendor = JvmVendorSpec.ORACLE
  }
}

javadoc {
  options.addStringOption('Xdoclint:none', '-quiet')
}

tasks.withType(JavaCompile) {
  options.compilerArgs << '-Xlint:unchecked'
  options.deprecation = true
}

dependencyLocking {
  lockAllConfigurations()
}

checkstyle {
  setMaxWarnings(0)
  setToolVersion(libs.versions.checkstyle.get())
}

sonarLint {
  languages {
    include('java')
  }
  rules {
    enable(
      'java:S4266', // "Stream.collect()" calls should not be redundant
    )
    disable(
      'java:S107', // Allow constructors with more than 7 parameters
      'java:S3776', // Allow methods with more than 15 lines
      'java:S4032', // Allow packages only containing `package-info.java`
    )
  }
}

strictNullCheck {
  addEclipse()
  packageInfo.useEclipse()
}

repositories {
  mavenCentral()
}

dependencies {
  annotationProcessor(libs.lombok)
  compileOnly(libs.lombok)
  sonarlintCorePlugins(libs.sonarlint.java)

  implementation(localGroovy())
  implementation(libs.maybe)
}

testing {
  suites {
    configureEach {
      useJUnitJupiter(libs.versions.junit.get())

      dependencies {
        annotationProcessor(libs.lombok)
        compileOnly(libs.lombok)

        implementation(libs.assertj)
        implementation(libs.mockito)
      }
    }

    testkit(JvmTestSuite) {
      dependencies {
        implementation(gradleTestKit())
      }

      targets {
        configureEach {
          testTask.configure {
            shouldRunAfter(test)
          }
        }
      }
    }
  }
}

prettyJupiter {
  failure {
    maxMessageLines = 30
  }
  duration {
    customThreshold = [testkit: 1000]
  }
}

gradlePlugin {
  website = 'https://joselion.github.io/strict-null-check/'
  vcsUrl = 'https://github.com/joselion/strict-null-check'

  plugins {
    strictNullCheck {
      id = 'io.github.joselion.strict-null-check'
      implementationClass = 'io.github.joselion.strictnullcheck.StrictNullCheckPlugin'
      displayName = 'Strict Null Check Plugin'
      description = 'A Gradle plugin to add full Strict Null Check to your Java code'
      tags.set([
        'nullability',
        'strict-null',
        'nonnull',
        'null-check',
        'non-null-by-default',
        'package-info-generation',
        'sonarlint'
      ])
    }
  }

  testSourceSets(sourceSets.testkit)
}

tasks.named('check') {
  dependsOn(testing.suites.testkit)
}